% V20210224 - 4.2.3 Page Transitions

INCLUDE "GW.bas"

% Create transition array.
ARRAY.LOAD transition$[], "fade", "flip", "flow", "none", "pop", "slide", "slidedown", "slidefade", "slideup", "turn"

% Create a titlebar button.
GW_USE_THEME_CUSTO_ONCE("notext icon=power")
btn$ = GW_ADD_BAR_RBUTTON$(">BACK")

% Create two footbar buttons.
GW_USE_THEME_CUSTO_ONCE("notext icon=arrow-l")
lbtn$ = GW_ADD_BAR_LBUTTON$(">PREV")

GW_USE_THEME_CUSTO_ONCE("notext icon=arrow-r")
rbtn$ = GW_ADD_BAR_RBUTTON$(">NEXT")

% Create 10 pages, one per transition.
DIM page[10]
FOR i = 1 TO 10
  page[i] = GW_NEW_PAGE()

  GW_SET_TRANSITION(page[i], transition$[i])
  GW_ADD_TITLEBAR(page[i], "Transition: " + transition$[i]  + btn$)
  GW_ADD_TEXT(page[i], ~
   "This app demonstrates the transitions when opening/closing a page.")
  GW_ADD_TEXT(page[i], ~
   "This is page #" + INT$(i) + " with the transition \"<b>" + ~
   transition$[i] + "</b>\"")
  e$ = GW_ADD_BAR_TITLE$("Page #" + INT$(i))
  GW_ADD_FOOTBAR(page[i], lbtn$ + e$ + rbtn$)
NEXT

% Display page #1.
idx = 1
GW_RENDER(page[idx])

% Handle user input.
DO
 r$ = GW_WAIT_ACTION$()

 % Place here any necessary code to process user actions.
  
 % User tapped "Next page" button
 IF r$ = "NEXT"
  idx = MOD(idx, 10) + 1
  GW_RENDER(page[idx])

 % User tapped "Previous page" button
 ELSEIF r$ = "PREV"
  idx = idx - 1
  IF idx = 0 THEN idx = 10
  GW_RENDER(page[idx])

 ENDIF

UNTIL r$ = "BACK"

END "End of Page Transitions example"